Numbers
*******

Integers are the only kind of number in version 18 Emacs Lisp.  These are whole numbers such as -3, 0, 7, 13, and 511.

In version 19, there is a compile time option to support floating point numbers, which are represented internally as the C type double. A floating point number is a number with a fractional part, such as -4.5, 0.0, or 2.71828.  A floating point number can be expressed in an exponential notation as well: thus, 1.5e2 equals 150; in this example, e2 stands for ten to the second power, and is multiplied by 1.5.

Number Basics
=============

The range of values for an integer depends on the machine.  The range is -8388608 to 8388607 (24 bits; i.e., -2**23 to 2**23 - 1 ) on most machines, but on others it is -16777216 to 16777215 (25 bits), or -33554432 to 33554431 (26 bits).  All of the examples shown below assume an integer has 24 bits.

The Lisp reader reads numbers as a sequence of digits with an optional sign.

     1                ; The integer 1.
     +1               ; Also the integer 1.
     -1               ; The integer -1.
     16777217         ; Also the integer 1, due to overflow.
     0                ; The number 0.
     -0               ; The number 0.
     1.               ; Invalid syntax.

To understand how various functions work on integers, especially the bitwise operators (see Bitwise Operations), it is often helpful to view the numbers in their binary form.

In 24 bit binary, the decimal integer 5 looks like this:

     0000 0000  0000 0000  0000 0101

(We have inserted spaces between groups of 4 bits, and two spaces between groups of 8 bits, to make the binary integer easier to read.)

The integer -1 looks like this:

     1111 1111  1111 1111  1111 1111

-1 is represented as 24 ones.  (This is called two's complement notation.)

The negative integer, -5, is creating by subtracting 4 from -1.  In binary, the decimal integer 4 is 100.  Consequently, -5 looks like this:

     1111 1111  1111 1111  1111 1011

In this implementation, the largest 24 bit binary integer is the decimal integer 8,388,607.  In binary, this number looks like this:

     0111 1111  1111 1111  1111 1111

Since the arithmetic functions do not check whether integers go outside their range, when you add 1 to 8,388,607, the value is negative integer -8,388,608:

     (+ 1 8388607)
          => -8388608
          => 1000 0000  0000 0000  0000 0000

Many of the following functions accept markers for arguments as well as integers.  (see Markers.)  More precisely, the actual parameters to such functions may be either integers or markers, which is why we often give these parameters the name MARKER-OR-INT.  When the actual parameter is a marker, the position value of the marker is used and the buffer of the marker is ignored.

Type Predicates for Numbers
===========================

The functions in this section test whether the argument is a number or whether it is a certain sort of number.  integerp and natnump can take any type of Lisp object as argument (the predicates would not be of much use otherwise); but the zerop predicate requires an integer as its argument.

 -- Function: integerp object
     This predicate tests whether its argument is an integer (a whole number) and returns t if so, nil otherwise.

 -- Function: natnump object
     The natnump predicate (whose name comes from the phrase ``natural-number-p'') tests to see whether its argument is a nonnegative integer, and returns t if so, nil otherwise.  0 is considered non-negative.

     Markers are not converted to integers, hence natnump of a marker is always nil.

     People have pointed out that this function is misnamed, because the term ``natural number'' is usually understood as excluding zero.  We are open to suggestions for a better name to use in version 19.

 -- Function: zerop integer
     This predicate tests whether its argument is zero, and returns t if so, nil otherwise.  These two forms are equivalent: (zerop x) == (= x 0).

Comparison of Numbers
=====================

The integer type is implemented by storing the value in the ``pointer part'' of a Lisp object (which, on typical target machines, has 24 bits of pointer, 7 bits of type and 1 bit for the garbage collector). Because of this, the function eq will return t for two integers with the same value.  See Equality Predicates.

     Common Lisp note: because of the way numbers are implemented in Common Lisp, you generally need to use = to test for equality between numbers.  However, GNU Emacs Lisp does not need very large integers; as a consequence, it is possible to restrict them to the size of a single word, allowing eq to be used.

 -- Function: = marker-or-int1 marker-or-int2
     This function tests whether its arguments are the same number, and returns t if so, nil otherwise.

 -- Function: /= marker-or-int1 marker-or-int2
     This function tests whether its arguments are not the same number, and returns t if so, nil otherwise.

 -- Function: < marker-or-int1 marker-or-int2
     This function tests whether its first argument is strictly less than its second argument.  It returns t if so, nil otherwise.

 -- Function: <= marker-or-int1 marker-or-int2
     This function tests whether its first argument is less than or equal to its second argument.  It returns t if so, nil otherwise.

 -- Function: > marker-or-int1 marker-or-int2
     This function tests whether its first argument is strictly greater than its second argument.  It returns t if so, nil otherwise.

 -- Function: >= marker-or-int1 marker-or-int2
     This function tests whether its first argument is greater than or equal to its second argument.  It returns t if so, nil otherwise.

 -- Function: max marker-or-int &rest markers-or-ints
     This function returns the largest of its arguments.

          (max 20)
               => 20
          (max 1 2)
               => 2
          (max 1 3 2)
               => 3

 -- Function: min marker-or-int &rest markers-or-ints
     This function returns the smallest of its arguments.

Arithmetic Operations
=====================

Emacs Lisp provides the traditional four arithmetic operations: addition, subtraction, multiplication, and division.  A remainder function supplements the (integer) division function.  In addition, as a convenience, incrementing and decrementing functions are provided.

It is important to note that in GNU Emacs Lisp, arithmetic functions do not check for overflow.  Thus (1+ 8388607) may equal -8388608, depending on your hardware.

 -- Function: 1+ marker-or-int
     This function adds one to MARKER-OR-INT.

 -- Function: 1- marker-or-int
     This function subtracts one from MARKER-OR-INT.

 -- Function: + &rest markers-or-ints
     This function adds its arguments together.  When given no arguments, + returns 0.  It does not check for overflow.

          (+)
               => 0
          (+ 1)
               => 1
          (+ 1 2 3 4)
               => 10

 -- Function: - &optional marker-or-int &rest other-markers-or-ints
     The - function serves two purposes: negation and subtraction. When - has a single argument, the value is the negative of the argument.  When there are multiple arguments, each of the OTHER-MARKERS-OR-INTS is subtracted from MARKER-OR-INT, cumulatively.  If there are no arguments, the result is 0.  This function does not check for overflow.

          (- 10 1 2 3 4)
               => 0
          (- 10)
               => -10
          (-)
               => 0

 -- Function: * &rest markers-or-integers
     This function multiplies its arguments together, and returns the product.  When given no arguments, * returns 1.  It does not check for overflow.

          (*)
               => 1
          (* 1)
               => 1
          (* 1 2 3 4)
               => 24

 -- Function: / dividend divisor &rest divisors
     This function divides DIVIDEND by DIVISORS and returns the quotient.  If there are additional arguments DIVISORS, then DIVIDEND is divided by each divisor in turn.    Each argument may be an integer or a marker.

     The result is normally rounded towars zero after each division, but some machines may round differently with negative arguments.  This is because the Lisp function / is implemented using the C division operator, which has the same possibility for machine-dependent rounding. In practice, all known machines round in the standard fashion.

     If you divide by 0, an arith-error error is signaled. (see Errors.)

          (/ 6 2)
               => 3
          (/ 5 2)
               => 2
          (/ 25 3 2)
               => 4
          (/ -17 6)
               => -2          ; (Could be -3 on some machines.)

 -- Function: % dividend divisor
     This function returns the value of DIVIDEND modulo DIVISOR; in other words, the integer remainder after division of DIVIDEND by DIVISOR.  The sign of the result is the sign of DIVIDEND. The sign of DIVISOR is ignored.  The arguments must be integers.

     For negative arguments, the value is in principle machine-dependent since the quotient is; but in practice, all known machines behave alike.

     An arith-error results if DIVISOR is 0.

          (% 9 4)
               => 1
          (% -9 4)
               => -1
          (% 9 -4)
               => 1
          (% -9 -4)
               => -1

     For any two numbers DIVIDEND and DIVISOR,

          (+ (% DIVIDEND DIVISOR)
             (* (/ DIVIDEND DIVISOR) DIVISOR))

     always equals DIVIDEND.

Bitwise Operations on Integers
==============================

In a computer, an integer is represented as a binary number, a sequence of bits (digits which are either zero or one).  A bitwise operation acts on the individual bits of such a sequence.  For example, shifting moves the whole sequence left or right one or more places, reproducing the same pattern ``moved over''.

The bitwise operations in Emacs Lisp apply only to integers.

 -- Function: lsh integer1 count
     lsh, which is an abbreviation for logical shift, shifts the bits in INTEGER1 to the left COUNT places, or to the right if COUNT is negative.  If COUNT is negative, lsh shifts zeros into the most-significant bit, producing a positive result even if INTEGER1 is negative.  Contrast this with ash, below.

     Thus, the decimal number 5 is the binary number 00000101.  Shifted once to the left, with a zero put in the one's place, the number becomes 00001010, decimal 10.

     Here are two examples of shifting the pattern of bits one place to the left.  Since the contents of the rightmost place has been moved one place to the left, a value has to be inserted into the rightmost place. With lsh, a zero is placed into the rightmost place.  (These examples show only the low-order eight bits of the binary pattern; the rest are all zero.)

          (lsh 5 1)
               => 10

          00000101 => 00001010     ; Decimal 5 becomes decimal 10.

          (lsh 7 1)
               => 14

          00000111 => 00001110     ; Decimal 7 becomes decimal 14.

     As the examples illustrate, shifting the pattern of bits one place to the left produces a number that is twice the value of the previous number.

     Note, however that functions do not check for overflow, and a returned value may be negative (and in any case, no more than a 24 bit value) when an integer is sufficiently left shifted.  For example:

          (lsh 8388607 1)          ; left shift
               => -2

     In binary, in the 24 bit implementation,

          0111 1111  1111 1111  1111 1111         ; Decimal 8,388,607

     becomes

          1111 1111  1111 1111  1111 1110         ; Decimal -2

     Shifting the pattern of bits two places to the left produces results like this (with 8-bit binary numbers):

          (lsh 3 2)
               => 12

          00000011 => 00001100       ; Decimal 3 becomes decimal 12.

     On the other hand, shifting the pattern of bits one place to the right looks like this:

          (lsh 6 -1)
               => 3

          00000110 => 00000011       ; Decimal 6 becomes decimal 3.

          (lsh 5 -1)
               => 2

          00000101 => 00000010       ; Decimal 5 becomes decimal 2.

     As the example illustrates, shifting the pattern of bits one place to the right divides the value of the binary number by two, rounding downward.

 -- Function: ash integer1 count
     ash (arithmetic shift) shifts the bits in INTEGER1 to the left COUNT places, or to the right if COUNT is negative.

     ash gives the same results as lsh except when INTEGER1 and COUNT are both negative.  In that case, ash puts a one in the leftmost position, while lsh puts a zero in the leftmost position.

     Thus, with ash, shifting the pattern of bits one place to the right looks like this:

          (ash -6 -1)
               => -3            ; Decimal -6 becomes decimal -3.

          1111 1111  1111 1111  1111 1010
               =>
          1111 1111  1111 1111  1111 1101

     In contrast, shifting the pattern of bits one place to the right with lsh looks like this:

          (lsh -6 -1)
               => 8388605       ; Decimal -6 becomes decimal 8,388,605.

          1111 1111  1111 1111  1111 1010
               =>
          0111 1111  1111 1111  1111 1101

     In this case, the 1 in the leftmost position is shifted one place to the right, and a zero is shifted into the leftmost position.

     Here are other examples:

                                 ;               24-bit binary values

          (lsh 5 2)              ;   5  =  0000 0000  0000 0000  0000 0101
               => 20             ;  20  =  0000 0000  0000 0000  0001 0100
          (ash 5 2)
               => 20
          (lsh -5 2)             ;  -5  =  1111 1111  1111 1111  1111 1011
               => -20            ; -20  =  1111 1111  1111 1111  1110 1100
          (ash -5 2)
               => -20

          (lsh 5 -2)             ;   5  =  0000 0000  0000 0000  0000 0101
               => 1              ;   1  =  0000 0000  0000 0000  0000 0001
          (ash 5 -2)
               => 1
          (lsh -5 -2)            ;  -5  =  1111 1111  1111 1111  1111 1011
               => 4194302        ;         0011 1111  1111 1111  1111 1110
          (ash -5 -2)            ;  -5  =  1111 1111  1111 1111  1111 1011
               => -2             ;  -2  =  1111 1111  1111 1111  1111 1110

 -- Function: logand &rest markers-or-ints
     This function returns the ``logical and'' of the arguments: the Nth bit is set in the result if, and only if, the Nth bit is set in all the arguments.  (``Set'' means that the value of the bit is 1 rather than 0.)

     For example, using 4-bit binary numbers, the ``logical and'' of 13 and 12 is 12: 1101 combined with 1100 produces 1100.

     In both the binary numbers, the leftmost two bits are set (i.e., they are 1's), so the leftmost two bits of the returned value are set. However, for the rightmost two bits, each is zero in at least one of the arguments, so the rightmost two bits of the returned value are 0's.

     Therefore,

          (logand 13 12)
               => 12

     If logand is not passed any argument, it returns a value of -1.  This number is an identity element for logand because its binary representation consists entirely of ones.  If logand is passed just one argument, it returns that argument.

                                 ;                24-bit binary values

          (logand 14 13)         ; 14  =  0000 0000  0000 0000  0000 1110
                                 ; 13  =  0000 0000  0000 0000  0000 1101
               => 12             ; 12  =  0000 0000  0000 0000  0000 1100

          (logand 14 13 4)       ; 14  =  0000 0000  0000 0000  0000 1110
                                 ; 13  =  0000 0000  0000 0000  0000 1101
                                 ;  4  =  0000 0000  0000 0000  0000 0100
               => 4              ;  4  =  0000 0000  0000 0000  0000 0100

          (logand)
               => -1             ; -1  =  1111 1111  1111 1111  1111 1111

 -- Function: logior &rest markers-or-ints
     This function returns the ``inclusive or'' of its arguments: the Nth bit is set in the result if, and only if, the Nth bit is set in at least one of the arguments.  If there are no arguments, the result is zero, which is an identity element for this operation.  If logior is passed just one argument, it returns that argument.

                                 ;               24-bit binary values

          (logior 12 5)          ; 12  =  0000 0000  0000 0000  0000 1100
                                 ;  5  =  0000 0000  0000 0000  0000 0101
               => 13             ; 13  =  0000 0000  0000 0000  0000 1101

          (logior 12 5 7)        ; 12  =  0000 0000  0000 0000  0000 1100
                                 ;  5  =  0000 0000  0000 0000  0000 0101
                                 ;  7  =  0000 0000  0000 0000  0000 0111
               => 15             ; 15  =  0000 0000  0000 0000  0000 1111

 -- Function: logxor &rest markers-or-ints
     This function returns the ``exclusive or'' of its arguments: the Nth bit is set in the result if, and only if, the Nth bit is set in an odd number of the arguments.  If there are no arguments, the result is 0.  If logxor is passed just one argument, it returns that argument.

                                 ;               24-bit binary values

          (logxor 12 5)          ; 12  =  0000 0000  0000 0000  0000 1100
                                 ;  5  =  0000 0000  0000 0000  0000 0101
               => 9              ;  9  =  0000 0000  0000 0000  0000 1001

          (logxor 12 5 7)        ; 12  =  0000 0000  0000 0000  0000 1100
                                 ;  5  =  0000 0000  0000 0000  0000 0101
                                 ;  7  =  0000 0000  0000 0000  0000 0111
               => 14             ; 14  =  0000 0000  0000 0000  0000 1110

 -- Function: lognot integer
     This function returns the logical complement of its argument: the Nth bit is one in the result if, and only if, the Nth bit is zero in INTEGER, and vice-versa.

          (lognot 5)             ;  5  =  0000 0000  0000 0000  0000 0101
               => -6             ; -6  =  1111 1111  1111 1111  1111 1010

Random Numbers
==============

 -- Function: random &optional flag
     This function returns a pseudo-random number of type integer.  When called more than once, this function returns a series of pseudo-random numbers.

     In a computer, a series of a pseudo-random numbers is generated in a deterministic fashion.  The numbers are not truly random, but they have certain properties that mimic a random series.  For example, all possible values occur equally often in a pseudo-random series.

     In Emacs, pseudo-random numbers are generated from a ``seed'' number. If the random function starts with the same seed, it generates the same sequence of numbers.  Emacs always starts with the same seed value, so the sequence of values of random is actually the same in each Emacs run!  For example, in one operating system, the first call to (random) after you start Emacs always returns -1457731, and the second one always returns -7692030.  This is helpful for debugging.

     If you want different random numbers, execute (random t).  This chooses a new seed based on the current time of day and on Emacs' process ID number.

     On some machines, any integer representable in Lisp may be the result of random.  On other machines, the result can never be larger than a certain maximum or less than a certain (negative) minimum.