Files
*****

In Emacs, you can find, create, view, save, and otherwise work with files and file directories.  This chapter describes most of the file-related functions of Emacs Lisp, but a few others are described in Buffers, and those related to backups and auto-saving are described in Backups and Auto-Saving.

Visiting Files
==============

Visiting a file means reading a file into a buffer.  Once this is done, we say that the buffer is visiting that file, and call the file ``the visited file'' of the buffer.

A file and a buffer are two different things.  A file is information recorded permanently in the computer (unless you delete it).  A buffer, on the other hand, is information inside of Emacs that will vanish at the end of the editing session (or when you kill the buffer).  Usually, a buffer contains information that you have copied from a file; then we say the buffer is visiting that file.  The copy in the buffer is what you modify with editing commands.  Such changes to the buffer do not change the file; therefore, to make the changes permanent, you must save the buffer, which means copying the altered buffer contents back into the file.

In spite of the distinction between files and buffers, people often refer to a file when they mean a buffer and vice-versa.  Indeed, we say, ``I am editing a file,'' rather than, ``I am editing a buffer which I will soon save as a file of the same name.''  Humans do not usually need to make the distinction explicit.  When dealing with a computer program, however, it is good to keep the distinction in mind.

Functions for Visiting Files
----------------------------

This section describes the functions normally used to visit files. For historical reasons, these functions have names starting with find- rather than visit-.  See Buffer File Name, for functions and variables that access the visited file name of a buffer or that find an existing buffer by its visited file name.

 -- Command: find-file filename
     This function reads the file FILENAME into a buffer and displays that buffer in the selected window so that the user can edit it.

     The body of the find-file function is very simple and looks like this:

          (switch-to-buffer (find-file-noselect filename))

     (See switch-to-buffer in Displaying Buffers.)

     When find-file is called interactively, it prompts for FILENAME in the minibuffer.

 -- Function: find-file-noselect filename
     This function is the guts of all the file-visiting functions.  It reads a file into a buffer and returns the buffer.  You may then make the buffer current or display it in a window if you wish, but this function does not do so.

     If no buffer is currently visiting FILENAME, then one is created and the file is visited.  If FILENAME does not exist, the buffer is left empty, and find-file-noselect displays the message New file in the echo area.

     If a buffer is already visiting FILENAME, then find-file-noselect uses that buffer rather than creating a new one.  However, it does verify that the file has not changed since it was last visited or saved in that buffer.  If the file has changed, then this function asks the user whether to reread the changed file.  If the user says yes, any changes previously made in the buffer will be lost.

     The find-file-noselect function calls after-find-file after the file is read in (see Subroutines of Visiting).  The after-find-file function sets the buffer major mode, parses local variables, warns the user if there exists an auto-save file more recent than the file just visited, and finishes by running the functions in find-file-hooks.

     The find-file-noselect function returns the buffer that is visiting the file FILENAME.

          (find-file-noselect "/etc/fstab")
               => #<buffer fstab>

 -- Command: find-alternate-file filename
     This function reads the file FILENAME into a buffer and selects it, killing the buffer current at the time the command is run.  It is useful if you have visited the wrong file by mistake, so that you can get rid of the buffer that you did not want to create, at the same time as you visit the file you intended.

     When this function is called interactively, it prompts for FILENAME.

 -- Command: find-file-other-window filename
     This function visits the file FILENAME and displays its buffer in a window other than the selected window.  If there are two or more windows on the screen, then the window that is not selected is used.  If there is only one window, it is split.  The function returns nil.

     When this function is called interactively, it prompts for FILENAME.

 -- Command: find-file-read-only filename
     This function visits the file named FILENAME and selects its buffer, just like find-file, but it marks the buffer as read-only.  See Read Only Buffers, for related functions and variables.

     When this function is called interactively, it prompts for FILENAME.

 -- Command: view-file filename
     This function views FILENAME in View mode, returning to the previous buffer when done.  View mode is a mode that allows you to skim rapidly through the file but does not let you modify it.

     After loading the file, view-file calls the value of view-hook if that is non-nil.

     When this function is called interactively, it prompts for FILENAME.

 -- Variable: find-file-hooks
     The value of this variable is a list of functions to be called after a file is visited.  The file's local-variables specification (if any) will have been processed before the hooks are run.  The buffer visiting the file is current when the hook functions are run.

 -- Variable: find-file-not-found-hooks
     The value of this variable is a list of functions to be called when find-file or find-file-noselect is passed a nonexistent FILENAME.  These functions are called as soon as the error is detected.  buffer-file-name is already set up.  The functions are called in the order given, until one of them returns non-nil.

Subroutines of Visiting
-----------------------

The find-file-noselect function uses the create-file-buffer and after-find-file functions as subroutines.  Sometimes it is useful to call them directly.

 -- Function: create-file-buffer filename
     This function creates a suitably named buffer for visiting FILENAME, and returns it.  The string FILENAME (sans directory) is used unchanged if that name is free; otherwise, a string such as <2> is appended to get an unused name.  See also Creating Buffers.

     Note: create-file-buffer does not associate the new buffer with a file and does not make it the current buffer.

          (create-file-buffer "foo")
               => #<buffer foo>
          (create-file-buffer "foo")
               => #<buffer foo<2>>
          (create-file-buffer "foo")
               => #<buffer foo<3>>

     This function is used by find-file-noselect.

 -- Function: after-find-file &optional error warn
     This function is called by find-file-noselect and by the default revert function (see Reverting).  It sets the buffer major mode, and parses local variables (see Auto Major Mode).

     If there was an error in opening the file, the calling function should pass ERROR a non-nil value.  In that case, after-find-file issues a warning: (New File).  Note that, for serious errors, you would not even call after-find-file. Only ``file not found'' errors get here with a non-nil ERROR.

     If WARN is non-nil, then this function issues a warning if an auto-save file exists and is more recent than the visited file.

     The last thing after-find-file does is call all the functions in find-file-hooks.

Saving Buffers
==============

When you edit a file in Emacs, you are actually working on a buffer that is visiting that file---that is, the contents of the file are copied into the buffer and the copy is what you edit.  Changes to the buffer do not change the file until you save the buffer, which means copying the contents of the buffer into the file.

 -- Command: save-buffer &optional backup-option
     This function saves the contents of the current buffer in its visited file if the buffer has been modified since it was last visited or saved. Otherwise it does nothing.

     save-buffer is responsible for making backup files.  Normally, BACKUP-OPTION is nil, and save-buffer makes a backup file only if this is the first save or if the buffer was previously modified.  Other values for BACKUP-OPTION request the making of backup files in other circumstances:

       * With an argument of 4 or 64, reflecting 1 or 3 C-u's, the save-buffer function marks this version of the file to be backed up when the buffer is next saved.

       * With an argument of 16 or 64, reflecting 2 or 3 C-u's, the save-buffer function unconditionally backs up the previous version of the file before saving it.

 -- Command: save-buffers-kill-emacs &optional kill-silently-p
     This function offers to save each buffer that needs to be saved, and then kills the Emacs job.  With a non-nil value of the optional KILL-SILENTLY-P argument, it unconditionally and silently saves all the file-visiting buffers, and then kills the job.

     The save-buffers-kill-emacs function is defined as follows:

          (defun save-buffers-kill-emacs (&optional arg)
            "Offer to save each buffer, then kill this Emacs fork..."
            (interactive "P")
            (save-some-buffers arg t)
            (kill-emacs))

 -- Command: save-some-buffers &optional save-silently-p exiting
     This command saves some modified file-visiting buffers.  Normally it asks the user about each buffer.  If the function is called with a non-nil value of the optional SAVE-SILENTLY-P argument, this function saves all the file-visiting buffers without querying the user.

     The optional EXITING argument, if non-nil, requests this function to offer also to save certain other buffers that are not visiting files.  These are buffers that have a non-nil local value of buffer-offer-save.  (A user who says yes to saving one of these will be asked to specify a file name to use.)  The save-buffers-kill-emacs function passes a non-nil value for this argument.

 -- Variable: buffer-offer-save
     When this variable is non-nil in a buffer, Emacs offers to save the buffer on exit even if the buffer is not visiting a file.  The variable is automatically local in all buffers.  Normally, Mail mode (used for editing outgoing mail) sets this to t.

 -- Command: write-file filename
     This function writes the current buffer into file FILENAME, makes the buffer visit that file, and marks it not modified.  The buffer is renamed to correspond to FILENAME unless that name is already in use.

 -- Variable: write-file-hooks
     The value of this variable is a list of functions to be called before writing out a buffer to its visited file.  If one of them returns non-nil, the file is considered already written and the rest of the functions are not called, nor is the usual code for writing the file executed.

     If the file-precious-flag variable is nil, the file is moved to the backup file before any of the hooks are called.  If none of the hooks actually write the file, but one does return non-nil, the file will not exist, although the backup will.

     Here is an example showing how to add an element to write-file-hooks but avoid adding it twice:

          (or (memq 'my-write-file-hook write-file-hooks)
              (setq write-file-hooks
                    (cons 'my-write-file-hook write-file-hooks)))

 -- Variable: file-precious-flag
     If this variable is non-nil, then save-buffer protects against I/O errors while saving by renaming the original file to a temporary name before writing the new contents of the file.  If the new contents are successfully written, the renamed original file is deleted. Otherwise, it is renamed back to the original name.  This procedure prevents problems such as a lack of disk space from resulting in an invalid file.

     Some modes set this non-nil locally in particular buffers.

 -- User Option: require-final-newline
     This variable determines whether files may be written out that do not end with a newline.  If the value of the variable is t, then Emacs silently puts a newline at the end of the file whenever the buffer being saved does not already end in one.  If the value of the variable is non-nil, but not t, then Emacs asks the user whether to add a newline each time the case arises.

     If the value of the variable is nil, then Emacs doesn't add newlines at all.  nil is the default value, but a few major modes change it to t.

Reading from Files
==================

You can copy a file directly from the disk and insert it into a buffer using the insert-file-contents function, or its interactive variant, insert-file.

 -- Command: insert-file filename
     This function inserts the contents of file FILENAME into the current buffer after point, and sets the mark at the end of the inserted text.  An error is signaled if FILENAME is not the name of a file that can be read.  This function is for interactive use and does little more than call insert-file-contents.

 -- Function: insert-file-contents filename &optional visit
     This function inserts the contents of file FILENAME into the current buffer after point. It returns a list of the absolute file name and the length of the data inserted.  An error is signaled if FILENAME is not the name of a file that can be read.

     If VISIT is non-nil, it also marks the buffer as unmodified and sets up various fields in the buffer so that it is visiting the file FILENAME: these include the buffer's visited file name and its last save file modtime.  This feature is used by find-file-noselect and you should probably not use it yourself.

Writing to Files
================

You can write the contents of a buffer, or part of a buffer, directly to a file on disk using the append-to-file and write-region functions.  Don't use these functions to write to files that are being visited; that could cause confusion in the mechanisms for visiting.

 -- Command: append-to-file start end filename
     This function appends the contents of the region delimited by START and END in the current buffer to the end of file FILENAME.  If that file does not exist, it is created.  This function returns nil.

     An error is signaled if FILENAME specifies a nonwritable file, or a nonexistent file in a directory where files cannot be created.

 -- Command: write-region start end filename &optional append visit
     This function writes the region (of the current buffer) delimited by START and END into the file specified by FILENAME.

     If APPEND is non-nil, then the region is appended to the existing file contents (if any).

     If VISIT is t, then Emacs establishes an association between the buffer and the file: the buffer is then visiting that file. It also sets the last file modification time for the current buffer to FILENAME's modtime, and marks the buffer as not modified.  This feature is used by write-file and you should probably not use it yourself.

     Normally, this function displays a message Wrote file FILENAME in the echo area.  If VISIT is neither t nor nil, then this message is inhibited.  This feature is useful for programs that use files for internal purposes, files which the user does not need to know about.

File Locks
==========

When two users edit the same file at the same time, they are likely to interfere with each other.  Emacs tries to prevent this situation from arising by recording a file lock when a file is being modified. Emacs can then detect the first attempt to modify a buffer visiting a file that is locked by another Emacs job, and ask the user what to do.

File locks do not work properly when multiple machines can share filesystems, such as with NFS.  Perhaps a better file locking system will be implemented in the future.  When file locks do not work, it is possible for two users to make changes simultaneously, but Emacs will still be able to warn the user who saves second.  Also, the detection of modification of a buffer visiting a file changed on disk catches some cases of simultaneous editing; see Modification Time.

 -- Function: file-locked-p filename
     This function returns nil if the file FILENAME is not locked by this Emacs process.  It returns t if it is locked by this Emacs, and it returns the name of the user who has locked it if it is locked by someone else.

          (file-locked-p "foo")
               => nil

 -- Function: lock-buffer &optional filename
     This function locks the file FILENAME, if the current buffer is modified.  The argument FILENAME defaults to the current buffer's visited file.  Nothing is done if the current buffer is not visiting a file, or is not modified.

 -- Function: unlock-buffer
     This function unlocks the file being visited in the current buffer, if the buffer is modified.  If the buffer is not modified, then the file should not be locked, so this function does nothing.  It also does nothing if the current buffer is not visiting a file.

 -- Function: ask-user-about-lock file other-user
     This function is called when the user tries to modify FILE, but it is locked by another user name OTHER-USER.  The value it returns controls what Emacs will do with the file:

       * A value of t tells Emacs to grab the lock on the file.  Then this user may edit the file and OTHER-USER loses the lock.

       * A value of nil tells Emacs to ignore the lock and let this user edit the file anyway.

       * This function may instead signal a file-locked error, in which case the change to the buffer which the user was about to make does not take place.

          The error message for this error looks like this:

               error--> File is locked: FILE OTHER-USER

          where file is the name of the file and OTHER-USER is the name of the user who has locked the file.

     The default definition of this function asks the user to choose what to do.  If you wish, you can replace the ask-user-about-lock function with your own version that decides in another way.  The code for its usual definition is in userlock.el.

Information about Files
=======================

The functions described in this section are similar in as much as they all operate on strings which are interpreted as file names.  All have names that begin with the word file.  These functions all return information about actual files or directories, so their arguments must all exist as actual files or directories unless otherwise noted.

Most of the file-oriented functions take a single argument, FILENAME, which must be a string.  The file name is expanded using expand-file-name, so ~ is handled correctly, as are relative file names (including ../).  Environment variable substitutions, such as $HOME, are not recognized by these functions.

Testing Accessibility
---------------------

These functions test for permission to access a file in specific ways.

 -- Function: file-exists-p filename
     This function returns t if a file named FILENAME appears to exist.  This does not mean you can necessarily read the file, only that you can find out its attributes.  (On Unix, this is true if the file exists and you have execute permission on the containing directories, regardless of the protection of the file itself.)

     If the file does not exist, or if fascist access control policies prevent you from finding the attributes of the file, this function returns nil.

 -- Function: file-readable-p filename
     This function returns t if a file named FILENAME exists and you can read it.  It returns nil otherwise.

          (file-readable-p "files.texi")
               => t
          (file-exists-p "/usr/spool/mqueue")
               => t
          (file-readable-p "/usr/spool/mqueue")
               => nil

 -- Function: file-writable-p filename
     This function returns t if FILENAME can be written or created by you.  It is writable if the file exists and you can write it. It is creatable if the file does not exist, but the specified directory does exist and you can write in that directory.  file-writable-p returns nil otherwise.

     In the third example below, foo is not writable because the parent directory does not exist, even though the user could create it.

          (file-writable-p "~rms/foo")
               => t
          (file-writable-p "/foo")
               => nil
          (file-writable-p "~rms/no-such-dir/foo")
               => nil

 -- Function: file-newer-than-file-p filename1 filename2
     This functions returns t if the file FILENAME1 is newer than file FILENAME2.  If FILENAME1 does not exist, it returns nil.  If FILENAME2 does not exist, it returns t.

     In the following example, assume that the file aug-19 was written on the 19th, and aug-20 was written on the 20th.  The file no-file doesn't exist at all.

          (file-newer-than-file-p "aug-19" "aug-20")
               => nil
          (file-newer-than-file-p "aug-20" "aug-19")
               => t
          (file-newer-than-file-p "aug-19" "no-file")
               => t
          (file-newer-than-file-p "no-file" "aug-19")
               => nil

Distinguishing Kinds of Files
-----------------------------

This section describes how to distinguish directories and symbolic links from ordinary files.

 -- Function: file-symlink-p filename
     If FILENAME is a symbolic link, the file-symlink-p function returns the file name to which it is linked.  This may be the name of a text file, a directory, or even another symbolic link, or of no file at all.

     If FILENAME is not a symbolic link (or there is no such file), file-symlink-p returns nil.

          (file-symlink-p "foo")
               => nil
          (file-symlink-p "sym-link")
               => "foo"
          (file-symlink-p "sym-link2")
               => "sym-link"
          (file-symlink-p "/bin")
               => "/pub/bin"

 -- Function: file-directory-p filename
     This function returns t if FILENAME is the name of an existing directory, nil otherwise.

          (file-directory-p "~rms")
               => t
          (file-directory-p "~rms/lewis/files.texi")
               => nil
          (file-directory-p "~rms/lewis/no-such-file")
               => nil
          (file-directory-p "$HOME")
               => nil
          (file-directory-p (substitute-in-file-name "$HOME"))
               => t

Other Information about Files
-----------------------------

This section describes the functions for getting detailed information about a file, other than its contents.  This information includes the mode bits that control access permission, the owner and group numbers, the number of names, the inode number, the size, and the times of access and modification.

 -- Function: file-modes filename
     This function returns the mode bits of FILENAME, as an integer. The mode bits are also called the file permissions, and they specify access control in the usual Unix fashion.  If the low-order bit is 1, then the file is executable by all users, if the second lowest-order bit is 1, then the file is writable by all users, etc.

     The highest value returnable is 4095 (7777 octal), meaning that everyone has read, write, and execute permission, that the SUID bit is set for both others and group, and that the sticky bit is set.

          (file-modes "~/junk/diffs")
               => 492               ; decimal integer
          (format "%o" 492)
               => 754               ; convert to octal

          (set-file-modes "~/junk/diffs" 438)
               => nil

          (format "%o" 438)
               => 666               ; convert to octal

          % ls -l diffs
            -rw-rw-rw-  1 lewis    0    3063 Oct 30 16:00 diffs

 -- Function: file-nlinks filename
     This functions returns the number of names (i.e., hard links) that file FILENAME has.  If the file does not exist, then this function returns nil.  Note that symbolic links have no effect on this function, because they are not considered to be names of the files they link to.

          % ls -l foo*
          -rw-rw-rw-  2 rms             4 Aug 19 01:27 foo
          -rw-rw-rw-  2 rms             4 Aug 19 01:27 foo1

          (file-nlinks "foo")
               => 2
          (file-nlinks "doesnt-exist")
               => nil

 -- Function: file-attributes filename
     This function returns a list of attributes of file FILENAME.  If the specified file cannot be opened, it returns nil.

     The elements of the list, in order, are:

      1. t for a directory, a string for a symbolic link (the name linked to), or nil for a text file.

      2. The number of names the file has.  Alternate names, also known as hard links, can be created with add-name-to-file (see Changing File Attributes).

      3. The file's UID.

      4. The file's GID.

      5. The time of last access, as a list of two integers. The first integer has the high-order 16 bits of time, the second has the low 16 bits.

      6. The time of last modification as a list of two integers (as above).

      7. The time of last status change as a list of two integers (as above).

      8. The size of the file in bytes.

      9. The file's modes, as a string of ten letters or dashes as in ls -l.

      10. t if the file's GID would change if file were deleted and recreated; nil otherwise.

      11. The file's inode number.

     For example, here are the file attributes for files.texi:

          (file-attributes "files.texi")
               =>  (nil
                    1
                    2235
                    75
                    (8489 20284)
                    (8489 20284)
                    (8489 20285)
                    14906
                    "-rw-rw-rw-"
                    nil
                    20920)

     and here is how the result is interpreted:

     nil
          is neither a directory nor a symbolic link.

     1
          has only one name (the name files.texi in the current default directory).

     2235
          is owned by the user with UID 2235.

     75
          is in the group with GID 75.

     (8489 20284)
          was last accessed on Aug 19 00:09.  Unfortunately, you cannot convert this number into a time string in Emacs.

     (8489 20284)
          was last accessed on Aug 19 00:09.

     (8489 20285)
          last had its inode changed on Aug 19 00:09.

     14906
          is 14906 characters long.

     "-rw-rw-rw-"
          has a mode of read and write access for the owner, group, and world.

     nil
          would retain the same GID if it were recreated.

     20920
          has an inode number of 20920.

Contents of Directories
=======================

A directory is a kind of file that contains other files entered under various names.  Directories are a feature of the file system.

Emacs can list the names of the files in a directory as a Lisp list, or display the names in a buffer using the ls shell command.  In the latter case, it can optionally display information about each file, depending on the value of switches passed to the ls command.

 -- Function: directory-files directory &optional full-name match-regexp
     This function returns a list of the names of the files in the directory DIRECTORY.

     If FULL-NAME is non-nil, the function returns the files' absolute file names.  Otherwise, it returns just the names relative to the specified directory.

     If MATCH-REGEXP is non-nil, function returns only those file names that contain that regular expression---the other file names are discarded from the list.

          (directory-files "~lewis")
               => ("#foo#" "#foo.el#" "." ".."
                   "dired-mods.el" "files.texi" "files.texi.~1~")

     An error is signaled if DIRECTORY is not the name of a directory that can be read.

 -- Function: file-name-all-versions file dirname
     This function returns a list of all versions of the file named FILE in directory DIRNAME.

 -- Command: list-directory filespec &optional verbose
     This command displays a list of files in or matching FILESPEC. It calls the shell command ls, passing it options under the control of VERBOSE.

     The argument FILESPEC may be either a directory name or a file name containing optional wildcards.  Wildcards are processed by the shell.

     The options passed to ls are the value of list-directory-verbose-switches if VERBOSE is non-nil; list-directory-brief-switches otherwise. Interactively, the raw prefix argument is used for VERBOSE.

 -- Variable: list-directory-brief-switches
     This variable contains switches for list-directory to pass to ls for a short or ``brief'' listing.  The default value is "-CF".

 -- Variable: list-directory-verbose-switches
     This variable contains switches for list-directory to pass to ls for a verbose or ``long'' listing.  The default value is "-l".

Changing File Names and Attributes
==================================

The functions in this section rename, copy, delete, link, and set the modes of files.

In the functions that have an argument NEWNAME, if a file by the name of NEWNAME already exists, the actions taken depend on the value of the argument OK-IF-ALREADY-EXISTS:

  * A file-already-exists error is signaled if OK-IF-ALREADY-EXISTS is nil.

  * Confirmation is requested if OK-IF-ALREADY-EXISTS is a number.

  * No confirmation is requested if OK-IF-ALREADY-EXISTS is any other value, in which case the old file is removed.

 -- Function: add-name-to-file oldname newname &optional ok-if-already-exists
     This function gives the file named OLDNAME the additional name NEWNAME.  This means that NEWNAME will be a new ``hard link'' to OLDNAME.

     In the first part of the following example, we list two files, foo and foo3.

          % ls -l fo*
          -rw-rw-rw-  1 rms            29 Aug 18 20:32 foo
          -rw-rw-rw-  1 rms            24 Aug 18 20:31 foo3

     Then we evaluate the form (add-name-to-file "~/lewis/foo" "~/lewis/foo2").  Again we list the files.  This shows two names, foo and foo2.

          (add-name-to-file "~/lewis/foo1" "~/lewis/foo2")
               => nil

          % ls -l fo*
          -rw-rw-rw-  2 rms            29 Aug 18 20:32 foo
          -rw-rw-rw-  2 rms            29 Aug 18 20:32 foo2
          -rw-rw-rw-  1 rms            24 Aug 18 20:31 foo3

     Finally, we evaluate (add-name-to-file "~/lewis/foo" "~/lewis/foo3" t), and list the files again.  Now there are three names for one file: foo, foo2, and foo3.  The old contents of foo3 are lost.

          (add-name-to-file "~/lewis/foo1" "~/lewis/foo3")
               => nil

          % ls -l fo*
          -rw-rw-rw-  3 rms            29 Aug 18 20:32 foo
          -rw-rw-rw-  3 rms            29 Aug 18 20:32 foo2
          -rw-rw-rw-  3 rms            29 Aug 18 20:32 foo3

     This function is meaningless on VMS, where multiple names for one file are not allowed.

     See also file-nlinks in Information about Files.

 -- Command: rename-file filename newname &optional ok-if-already-exists
     This command renames the file FILENAME as NEWNAME.

     If FILENAME has additional names aside from FILENAME, it continues to have those names.  In fact, adding the name NEWNAME with add-name-to-file and then deleting FILENAME has the same effect as renaming, aside from momentary intermediate states.

     In an interactive call, this function prompts for FILENAME and NEWNAME in the minibuffer; also, it requests confirmation if NEWNAME already exists.

 -- Command: copy-file oldname newname &optional ok-if-exists time
     This command copies the file OLDNAME to NEWNAME.  An error is signaled if OLDNAME does not exist.

     If TIME is non-nil, then this functions gives the new file the same last-modified time that the old one has.  (This works on only some operating systems.)

     In an interactive call, this function prompts for FILENAME and NEWNAME in the minibuffer; also, it requests confirmation if NEWNAME already exists.

 -- Command: delete-file filename
     This command deletes the file FILENAME, like the shell command rm FILENAME.  If the file has multiple names, it continues to exist under the other names.

     A suitable kind of file-error error is signaled if the file does not exist, or is not deletable.  (In Unix, a file is deletable if its directory is writable.)

 -- Command: make-symbolic-link filename newname &optional ok-if-exists
     This command makes a symbolic link to FILENAME, named NEWNAME.  This is like the shell command ln -s FILENAME NEWNAME.

     In an interactive call, FILENAME and NEWNAME are read in the minibuffer, and OK-IF-EXISTS is set to the numeric prefix argument.

 -- Function: set-file-modes filename mode
     This function sets mode bits of FILENAME to MODE (which must be a integer).  Only the 12 low bits of MODE are used.

File Names
==========

Files are generally referred to by their names, in Emacs as elsewhere. File names in Emacs are represented as strings.  The functions that operate on a file all expect a file name argument.

In addition to operating on files themselves, Emacs Lisp programs often need to operate on the names; i.e., to take them apart and to use part of a name to construct related file names.  This section describes how to manipulate file names.

The functions in this section do not actually access files, so they can operate on file names that do not refer to an existing file or directory.

On VMS, all these functions understand both VMS file name syntax and Unix syntax.  This is so that all the standard Lisp libraries can specify file names in Unix syntax and work properly on VMS without change.

File Name Components
--------------------

The operating system groups files into directories.  To specify a file, you must specify the directory, and the file's name in that directory.  Therefore, a file name in Emacs is considered to have two main parts: the directory name part, and the nondirectory part (or file name within the directory).  Either part may be empty.  Concatenating these two parts reproduces the original file name.

On Unix, the directory part is everything up to and including the last slash; the nondirectory part is the rest.  The rules in VMS syntax are complicated.

For some purposes, the nondirectory part is further subdivided into the name and the version number.  On Unix, only backup files have version numbers in their names; on VMS, every file has a version number, but most of the time the file name actually used in Emacs omits the version number.  Version numbers are found mostly in directory lists.

 -- Function: file-name-directory filename
     This function returns the directory part of FILENAME (or nil if FILENAME does not include a directory part).  On Unix, the function returns a string ending in a slash.  On VMS, it returns a string ending in one of the three characters :, ], or >.

          (file-name-directory "lewis/foo")     ; Unix example
               => "lewis/"
          (file-name-directory "foo")           ; Unix example
               => nil
          (file-name-directory "[X]FOO.TMP")    ; VMS example
               => "[X]"

 -- Function: file-name-nondirectory filename
     This function returns the nondirectory part of FILENAME.

          (file-name-nondirectory "lewis/foo")
               => "foo"
          (file-name-nondirectory "foo")
               => "foo"
          ;; The following example is accurate only on VMS.
          (file-name-nondirectory "[X]FOO.TMP")
               => "FOO.TMP"

 -- Function: file-name-sans-versions filename
     This function returns FILENAME without any file version numbers, backup version numbers, or trailing tildes.

          (file-name-sans-versions "~rms/foo.~1~")
               => "~rms/foo"
          (file-name-sans-versions "~rms/foo~")
               => "~rms/foo"
          (file-name-sans-versions "~rms/foo")
               => "~rms/foo"
          ;; The following example applies to VMS only.
          (file-name-sans-versions "foo;23")
               => "foo"

Directory Names
---------------

A directory name is the name of a directory.  A directory is a kind of file, and it has a file name, which is related to the directory name but not identical to it.  (This is not quite the same as the usual Unix terminology.)  These two different names for the same entity are related by a syntactic transformation.  On Unix, this is simple: a directory name ends in a slash, whereas the directory's name as a file lacks that slash.  On VMS, the relationship is more complicated.

The difference between a directory name and its name as a file is subtle but crucial.  When an Emacs variable or function argument is described as being a directory name, a file name of a directory is not acceptable.

All of these functions take a single argument, FILENAME, which must be a string.  Environment variable substitutions such as $HOME, and the symbols ~, and .., are not expanded.  Use expand-file-name or substitute-in-file-name for that (see File Name Expansion).

 -- Function: file-name-as-directory filename
     This function returns a string representing FILENAME in a form that the operating system will interpret as the name of a directory.  In Unix, this means that a slash is appended to the string.  On VMS, the function converts a string of the form [X]Y.DIR.1 to the form [X.Y].

          (file-name-as-directory "~rms/lewis")
               => "~rms/lewis/"

 -- Function: directory-file-name dirname
     This function returns a string representing DIRNAME in a form that the operating system will interpret as the name of a file.  On Unix, this means that a final slash is removed from the string.  On VMS, the function converts a string of the form [X.Y] to [X]Y.DIR.1.

          (directory-file-name "~lewis/")
               => "~lewis"

Absolute and Relative File Names
--------------------------------

All the directories in the file system form a tree starting at the root directory.  A file name can specify all the directory names starting from the root of the tree; then it is called an absolute file name.  Or it can specify the position of the file in the tree relative to a default directory; then it is called an relative file name.  On Unix, an absolute file name starts with a slash or a tilde (~), and a relative one does not.  The rules on VMS are complicated.

 -- Function: file-name-absolute-p filename
     This function returns t if file FILENAME is an absolute file name, nil otherwise.  On VMS, this function understands both Unix syntax and VMS syntax.

          (file-name-absolute-p "~rms/foo")
               => t
          (file-name-absolute-p "rms/foo")
               => nil
          (file-name-absolute-p "$HOME")
               => nil
          (file-name-absolute-p "/user/rms/foo")
               => t

Functions that Expand Filenames
-------------------------------

Expansion of a file name means converting a relative file name to an absolute one.  Since this is done relative to a default directory, you must specify the default directory name as well as the file name to be expanded.  Expansion also canonicalizes file names by eliminating redundancies such as ./ and NAME/../.

 -- Function: expand-file-name filename &optional directory
     This function converts FILENAME to an absolute file name.  If DIRECTORY is supplied, it is the directory to start with if FILENAME is relative.  Otherwise, the current buffer's value of default-directory is used.  For example:

          (expand-file-name "foo")
               => "/xcssun/users/rms/lewis/foo"
          (expand-file-name "../foo")
               => "/xcssun/users/rms/foo"
          (expand-file-name "foo" "/usr/spool")
               => "/usr/spool/foo"
          (expand-file-name "$HOME/foo")
               => "/xcssun/users/rms/lewis/$HOME/foo"

     Filenames containing . or .. are simplified to their canonical form:

          (expand-file-name "bar/../foo")
               => "/xcssun/users/rms/lewis/foo"

     ~/ is expanded into the user's home directory.  A / or ~ following a / is taken to be the start of an absolute file name that overrides what precedes it, so everything before that / or ~ is deleted.  For example:

          (expand-file-name "/a1/gnu//usr/local/lib/emacs/etc/MACHINES")
               => "/usr/local/lib/emacs/etc/MACHINES"
          (expand-file-name "/a1/gnu/~/foo")
               => "/xcssun/users/rms/foo"

     In both cases, /a1/gnu/ has been discarded because an absolute file name follows it.

     Note that expand-file-name does not expand environment variables; that is done only by substitute-in-file-name.

 -- Variable: default-directory
     The value of this buffer-local variable is the default directory for the current buffer.  It is local in every buffer. expand-file-name uses the default directory when its second argument is nil.

     On Unix systems, the value is always a string ending with a slash.

          default-directory
               => "/user/lewis/manual/"

 -- Function: substitute-in-file-name filename
     This function replaces environment variables names in FILENAME with the values to which they are set by the operating system. Following standard Unix shell syntax, $ is the prefix to substitute an environment variable value.

     The environment variable name is the series of alphanumeric characters (including underscores) that follow the $.  If the character following the $ is a {, then the variable name is everything up to the matching }.

     Here we assume that the environment variable HOME, which holds the user's home directory name, has the value /xcssun/users/rms.

          (substitute-in-file-name "$HOME/foo")
               => "/xcssun/users/rms/foo"

     If a ~ or a / appears following a /, after substitution, everything before the following / is discarded:

          (substitute-in-file-name "bar/~/foo")
               => "~/foo"
          (substitute-in-file-name "/usr/local/$HOME/foo")
               => "/xcssun/users/rms/foo"

     On VMS, $ substitution is not done, so this function does nothing on VMS except discard superfluous initial components as shown above.

Generating Unique File Names
----------------------------

Some programs need to write temporary files.  Here is the usual way to construct a name for such a file:

     (concat "/tmp/" (make-temp-name NAME-OF-APPLICATION))

The directory /tmp/ is chosen because that is the standard place on Unix for temporary files.  The task of make-temp-name is to prevent two different users or two different jobs from trying to use the same name.

 -- Function: make-temp-name string
     This function generates string that can be used as a unique name. The name will start with the prefix STRING, and finish with a number that is different in each Emacs job.

          (make-temp-name "foo")
               => "foo021304"
          (make-temp-name "foo")
               => "foo021304"

     To prevent conflicts among different application libraries run in the same Emacs, each application should have its own STRING.  The number added to the end of the name distinguishes between the same application running in different Emacses.

File Name Completion
--------------------

This section describes low-level subroutines for completing a file name.  For other completion functions, see Completion.

 -- Function: file-name-all-completions partial-filename directory
     This function returns a list of all possible completions for a file whose name starts with PARTIAL-FILENAME in directory DIRECTORY.  The order of the completions is the order of the files in the directory, which is unpredictable and conveys no useful information.

     The argument PARTIAL-FILENAME must be a file name containing no directory part and no slash.  The current buffer's default directory is prepended to DIRECTORY, if DIRECTORY is not an absolute file name.

     In the following example, suppose that the current default directory, ~rms/lewis, has five files whose names begin with f: foo, file~, file.c, file.c.~1~, and file.c.~2~.

          (file-name-all-completions "f" "")
               => ("foo" "file~" "file.c.~2~" "file.c.~1~" "file.c")

          (file-name-all-completions "fo" "")
               => ("foo")

 -- Function: file-name-completion filename directory
     This function completes the file name FILENAME in directory DIRECTORY.  It returns the longest prefix common to all file names in directory DIRECTORY that start with FILENAME.

     If only one match exists and FILENAME matches it exactly, the function returns t.  The function returns nil if directory DIRECTORY contains no name starting with FILENAME.

     In the following example, suppose that the current default directory has five files whose names begin with f: foo, file~, file.c, file.c.~1~, and file.c.~2~.

          (file-name-completion "fi" "")
               => "file"

          (file-name-completion "file.c.~1" "")
               => "file.c.~1~"

          (file-name-completion "file.c.~1~" "")
               => t

          (file-name-completion "file.c.~3" "")
               => nil

 -- User Option: completion-ignored-extensions
     file-name-completion usually ignores file names that end in any string in this list.  It does not ignore them when all the possible completions end in one of these suffixes or when a buffer showing all possible completions is displayed.

     A typical value might look like this:

          completion-ignored-extensions
               => (".o" ".elc" "~" ".dvi")